This could also be a nice usage of my old "ActiveArea" AVS script...
You could specify the x and y coordinates of the hardcoded subs and make this area black before adding the new subs. You would do it like this:
Paste the following into a new text file with the name "ActiveArea.avs"
Code:
# Define the coordinates of the desired active area
# X1 is left, Y1 is top, X2 is right, Y2 is bottom
X1 =
Y1 =
X2 =
Y2 =
# Make the values MOD4
X1 = X1 - (X1 % 4)
Y1 = Y1 - (y1 % 4)
X2 = (X2 + 3) / 4 * 4
Y2 = (Y2 + 3) / 4 * 4
Active = crop(X1,Y1,X2-X1,Y2-Y1)
Above = Y1 > 0 ? crop(0,0,width(),Y1) : NOP
Below = Y2 < height() ? crop(0,Y2,width(),height()-Y2) : NOP
Left = X1 > 0 ? crop(0,Y1,X1,Y2-Y1) : NOP
Right = X2 < width() ? crop(X2,Y1,width()-X2,Y2-Y1) : NOP
Last = Active
BlankClip(Active)
# My_Filter_2(...parameters...)
# My_Filter_3(...parameters...)
IsClip(Left) ? StackHorizontal(Left, Last) : NOP
IsClip(Right) ? StackHorizontal(Last, Right) : NOP
IsClip(Above) ? StackVertical(Above, Last) : NOP
IsClip(Below) ? StackVertical(Last, Below) : NOP
return Last
Find the coordinates of the hard coded subs and enter them into this script.
Now import the script into AVStoDVD (View/Edit Title Settings -> AviSynth). Uncheck "Auto AviSynth Script" and insert the following lines right after the "Video = Video.ConvertToYV12()" line:
Quote:
# Must be inserted into the AVS script after the "ConvertToYV12()" command
Last = Video
Import("FULL PATH\ActiveArea.avs")
Video = Last
|
Don't forget to specify the full path for the "ActiveArea" script.
After importing this script the whole hard subs area should be pitch black so you can overlay your new subs.
Good luck
manolito