RipBot264 v1.18.3 - Simple and easy to use GUI -> IPOD . PSP . CONSOLES . BLURAY

[TR-7970X]

Originally Posted by archiel

I was afraid that you might suggest that. I have had already run into SMB sharing issues using Everyone with other programs which suggests that there is a new security setting (or bug) in 24H2, but so far I have not seen any way of determining which it is or how to fix it.

Well, now I'm glad I'm not the only one having issues with 24H2.

I have tried every fix I can find, regarding this issue, and nothing works. Except what I suggested.

[archiel]

Originally Posted by TR-7970X

Well, now I'm glad I'm not the only one having issues with 24H2.

I have tried every fix I can find, regarding this issue, and nothing works. Except what I suggested.

Unfortunately your solution (clean install and then rebuild apps etc) takes a couple of days on my setup (I know i did it last November) so I think I will see if I can find anything with a couple of clean installs (23H2) and 24H2 and a something like regshot. Hopefully can find some time over the weekend and see if I find anything.

[TR-7970X]

Originally Posted by archiel

Unfortunately your solution (clean install and then rebuild apps etc) takes a couple of days on my setup (I know i did it last November) so I think I will see if I can find anything with a couple of clean installs (23H2) and 24H2 and a something like regshot. Hopefully can find some time over the weekend and see if I find anything.

Yes I know it's a PITA, but it's the only solution I've been able to come up with that let's RipBot work properly...

Until some brainiac on this forum comes up with a solution that actually does work, then that's it !

[dipais]

Originally Posted by Atak_Snajpera

I did not expect that...

Dear Atak Snajpera

There're some errors caused by the overlay script in RipBot. Sample video is here (1080p): https://mega.nz/file/QkpGETzI#7ud8IB...NzGlgk1BgsfexI

A. Overlay's Scaling Factor Error (UNRESIZED)

The error appears, see this pic, only at certain values ​​as shown below, it's when the video is NOT RESIZED.

| 0.03 | 0.06 | 0.08 | 0.13 | 0.16 | 0.18 | 0.23 | 0.26 | 0.28 | 0.33 | 0.36 | 0.38 | 0.43 | 0.46 | 0.48 |
| 0.53 | 0.56 | 0.58 | 0.63 | 0.66 | 0.68 | 0.73 | 0.76 | 0.78 | 0.83 | 0.86 | 0.88 | 0.93 | 0.97 | 0.98 |

B. Overlay's Scaling Factor Error (RESIZED)

Another error appears, also only at certain values, as listed below, it only occurs in conditions when the video is RESIZED from 1080p to a lower, either by selecting one of the predefined resolution options (i.e. HD-Ready 1280x720), or by specifying the desired resolution (i.e. Custom [1.78:1]).

| 0.04 | 0.07 | 0.09 | 0.14 | 0.17 | 0.19 | 0.24 | 0.27 | 0.29 | 0.34 | 0.37 | 0.39 | 0.44 | 0.47 | 0.49 |
| 0.54 | 0.57 | 0.59 | 0.64 | 0.67 | 0.69 | 0.74 | 0.77 | 0.79 | 0.84 | 0.87 | 0.89 | 0.94 | 0.98 | 0.99 |

Furthermore, the error occurs in two different messages as follows:

1. See this pic, it's when the downgrade is done via the options: HD-Ready 1280x720, PSP, iPHONE 480x270, and iPOD 320x240.
   
2. See this pic, it's when the downgrade is done via the options: Custom [1,78:1] and Custom [x,xx:x].

Would you like to tell me how do I fix that?. Thank you, Atak.

Cheers,
D

[rlev11]

Originally Posted by archiel

Okay - connect to ES is now fixed, password-less sharing is enabled and I am getting exactly the same error
Command "AUTHENTICATE" received from client
ERROR! File \\10.50.60.115\RipBot264Temp\job5\Chunks\1.cmd does not exist!

How did you eventually solve this?

So it appears to me the the main issue with 24H2 is if the PC acting as the DE client is a fresh install of 24H2. This is the PC where the ripbot temp folder will be located.
When I tested using one of my fresh 24h2 machines as a client, what I noticed is that the share permission is not being set correctly. On a box earlier than 24H2 or upgraded to 24H2, that share permission is set to everyone-full control. On the 24H2 PC from scratch acting as a client, the share permission on mine is set to "Builtin" with full control.

While the DE Client window is up and not connecting to anything at the start of a job, if you go into the share settings of the ripbot264temp folder and add everyone with full control, then connect each server in the client window, they will then connect and finish the job.

That share command must be sent to the folder programmatically at the start of each job, as once 1 job ends and another is started, the permissions reset back to "Builtin" and you would have to add in everyone again and repeat the process. I realize this is not an ideal work around....

24H2 must have changed something in the way someone can programmatically set a share permission.

This is a separate issue that may arise also, sharing without passwords with 24H2. I still had to turn off the smb signing on my server only fresh 24H2 installs to reach back to the client share.

Bottom Line is Microsoft really tightened down SMB with 24H2, and it is going to take some time and patience to work through everything.

[Atak_Snajpera]

This is my script for sharing C:\Temp\RipBot264temp folder (manually change it if it is necessary).
Paste this to notepad and save as ShareFolder.cmd . Run it as ADMINISTRATOR and check output messages.

set MySid=S-1-1-0
for /f "delims=' skip=1" %%a in ('"wmic path win32_account where SID='%MySid%' get name"') do (
      set myvar=%%a
      goto :loop_end
   )
)
:loop_end
 
call :Trim myvar %myvar%
call :Share
 
:Trim
SetLocal EnableDelayedExpansion
set params=%*
for /f "tokens=1*" %%a in ("!Params!") do EndLocal & set %1=%%b
exit /b
 
:Share 
net share RipBot264temp /DELETE /Y
net share RipBot264temp="C:\Temp\RipBot264temp" /GRANT:"%myvar%",FULL
icacls "C:\Temp\RipBot264temp" /T /C /Q /Grant:R %MySid%:(OI)(CI)F
icacls "C:\Temp\RipBot264temp" /T /C /Q /inheritance:e

pause

UPDATE: Looks like Microsoft removed WMIC.exe tool on 24H2 !!!

[rlev11]

Originally Posted by Atak_Snajpera

This is my script for sharing C:\Temp\RipBot264temp folder (manually change it if it is necessary).
Paste this to notepad and save as ShareFolder.cmd . Run it as ADMINISTRATOR and check output messages.

set MySid=S-1-1-0
for /f "delims=' skip=1" %%a in ('"wmic path win32_account where SID='%MySid%' get name"') do (
      set myvar=%%a
      goto :loop_end
   )
)
:loop_end
 
call :Trim myvar %myvar%
call :Share
 
:Trim
SetLocal EnableDelayedExpansion
set params=%*
for /f "tokens=1*" %%a in ("!Params!") do EndLocal & set %1=%%b
exit /b
 
:Share 
net share RipBot264temp /DELETE /Y
net share RipBot264temp="C:\Temp\RipBot264temp" /GRANT:"%myvar%",FULL
icacls "C:\Temp\RipBot264temp" /T /C /Q /Grant:R *%MySid%:(OI)(CI)F
icacls "C:\Temp\RipBot264temp" /T /C /Q /inheritance:e

pause

UPDATE: Looks like Microsoft removed WMIC.exe tool on 24H2 !!!

running it as administrator, not as admin on both pc's gives gives system error 5 on the net share commands

on client that works:
D:\>net share RipBot264temp="d:\Temp\RipBot264temp" /GRANT:"Everyone",FULL
RipBot264temp was shared successfully.

On one that doesn't:
D:\>net share RipBot264temp="D:\Temp\RipBot264temp" /GRANT:"",FULL
System error 3 has occurred.

If I hardcode /GRANT:"Everyone",FULL in place of the /GRANT:"%myvar%",FULL
it appears to be OK

[rlev11]

the icacls lines work fine, under the security tab everyone has full control even when the share does not work

[Atak_Snajpera]

Try this. WMIC replaced by Powershell by DeepSeek AI.
Fresh 24H2 does not have WMIC tool. When you upgrade from older version WMIC.exe is still there.

@echo off
setlocal enabledelayedexpansion

set "SID=S-1-1-0"

set "USERNAME="
for /f "delims=" %%a in ('
    powershell -Command "$sid = New-Object System.Security.Principal.SecurityIdentifier('%SID%'); try { $name = $sid.Translate([System.Security.Principal.NTAccount]).Value; Write-Output $name } catch { exit 1 }"
') do set "USERNAME=%%a"

if "%USERNAME%"=="" (
    echo No user name found for : %SID%
    exit /b 1
) else (
    echo Found user name for %SID%: %USERNAME%
)

endlocal


call :Trim myvar %USERNAME%
call :Share
 
:Trim
SetLocal EnableDelayedExpansion
set params=%*
for /f "tokens=1*" %%a in ("!Params!") do EndLocal & set %1=%%b
exit /b
 
:Share 
net share RipBot264temp /DELETE /Y
net share RipBot264temp="C:\Temp\RipBot264temp" /GRANT:"%myvar%",FULL
icacls "C:\Temp\RipBot264temp" /T /C /Q /Grant:R %Sid%:(OI)(CI)F
icacls "C:\Temp\RipBot264temp" /T /C /Q /inheritance:e

pause

[rlev11]

Originally Posted by Atak_Snajpera

Try this. WMIC replaced by Powershell by DeepSeek AI.
Fresh 24H2 does not have WMIC tool. When you upgrade from older version WMIC.exe is still there.

@echo off
setlocal enabledelayedexpansion

set "SID=S-1-1-0"

set "USERNAME="
for /f "delims=" %%a in ('
    powershell -Command "$sid = New-Object System.Security.Principal.SecurityIdentifier('%SID%'); try { $name = $sid.Translate([System.Security.Principal.NTAccount]).Value; Write-Output $name } catch { exit 1 }"
') do set "USERNAME=%%a"

if "%USERNAME%"=="" (
    echo No user name found for : %SID%
    exit /b 1
) else (
    echo Found user name for %SID%: %USERNAME%
)

endlocal


call :Trim myvar %USERNAME%
call :Share
 
:Trim
SetLocal EnableDelayedExpansion
set params=%*
for /f "tokens=1*" %%a in ("!Params!") do EndLocal & set %1=%%b
exit /b
 
:Share 
net share RipBot264temp /DELETE /Y
net share RipBot264temp="C:\Temp\RipBot264temp" /GRANT:"%myvar%",FULL
icacls "C:\Temp\RipBot264temp" /T /C /Q /Grant:R %Sid%:(OI)(CI)F
icacls "C:\Temp\RipBot264temp" /T /C /Q /inheritance:e

pause

D:\>set "USERNAME="

D:\>for /F "delims=" %a in (' powershell -Command "$sid = New-Object System.Security.Principal.SecurityIdentifier(''); try { $name = $sid.Translate([System.Security.Principal.NTAccount]).Value; Write-Output $name } catch { exit 1 }" ') do set "USERNAME=%a"

D:\>set "USERNAME=New-Object : Exception calling ".ctor" with "1" argument(s): "Value was invalid."

D:\>set "USERNAME=Parameter name: sddlForm""

D:\>set "USERNAME=At line:1 char:8"

D:\>set "USERNAME=+ $sid = New-Object System.Security.Principal.SecurityIdentifier(''); t ..."

D:\>set "USERNAME=+ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"

D:\>set "USERNAME= + CategoryInfo : InvalidOperation: ( [New-Object], MethodInvocationException"

D:\>set "USERNAME= + FullyQualifiedErrorId : ConstructorInvokedThrowException,Microsoft.PowerShell.Commands.NewObjectCommand"

D:\>set "USERNAME= "

D:\>if " " == "" (
echo No user name found for :
exit /b 1
) else (echo Found user name for : )
Found user name for :

D:\>endlocal

D:\>call :Trim myvar

D:\>SetLocal EnableDelayedExpansion

D:\>set params=myvar

D:\>for /F "tokens=1*" %a in ("!Params!") do EndLocal & set myvar=%b

D:\>EndLocal & set myvar=

D:\>exit /b

D:\>call :Share

D:\>net share RipBot264temp /DELETE /Y
RipBot264temp was deleted successfully.


D:\>net share RipBot264temp="D:\Temp\RipBot264temp" /GRANT:"",FULL
RipBot264temp was shared successfully.


D:\>icacls "D:\Temp\RipBot264temp" /T /C /Q /Grant:R OI)(CI)F
Successfully processed 420 files; Failed processing 0 files

D:\>icacls "d:\Temp\RipBot264temp" /T /C /Q /inheritance:e
Successfully processed 420 files; Failed processing 0 files

[Atak_Snajpera]

works fine on my 24h2 in VM (RUN AS ADMINISTRATOR)

[rlev11]

Originally Posted by Atak_Snajpera

works fine on my 24h2 in VM (RUN AS ADMINISTRATOR)

script now runs, I had the drives letters wriong. however the share permissions are set to my local account name, not everyone on my pc

just doing a %myvar% returns the local account name as well

D:\>%myvar%
'rleva' is not recognized as an internal or external command,
operable program or batch file.

[rlev11]

%Username% also returns my local account name

[Atak_Snajpera]

Originally Posted by rlev11

%Username% also returns my local account name

Try this

rem @echo off
setlocal enabledelayedexpansion

set "SID=S-1-1-0"

set "USER="
for /f "delims=" %%a in ('
    powershell -Command "$sid = New-Object System.Security.Principal.SecurityIdentifier('%SID%'); try { $name = $sid.Translate([System.Security.Principal.NTAccount]).Value; Write-Output $name } catch { exit 1 }"
') do set "USER=%%a"

if "%USER%"=="" (
    echo No username found for %SID%
    exit /b 1
) else (
    echo Found username for %SID%: %USER%
)

net share RipBot264temp /DELETE /Y
net share RipBot264temp="C:\Temp\RipBot264temp" /GRANT:"%USER%",FULL
icacls "C:\Temp\RipBot264temp" /T /C /Q /Grant:R *%SID%:(OI)(CI)F
icacls "C:\Temp\RipBot264temp" /T /C /Q /inheritance:e

endlocal

pause

[rlev11]

Originally Posted by Atak_Snajpera

Try this

rem @echo off
setlocal enabledelayedexpansion

set "SID=S-1-1-0"

set "USER="
for /f "delims=" %%a in ('
    powershell -Command "$sid = New-Object System.Security.Principal.SecurityIdentifier('%SID%'); try { $name = $sid.Translate([System.Security.Principal.NTAccount]).Value; Write-Output $name } catch { exit 1 }"
') do set "USER=%%a"

if "%USER%"=="" (
    echo No username found for %SID%
    exit /b 1
) else (
    echo Found username for %SID%: %USER%
)

net share RipBot264temp /DELETE /Y
net share RipBot264temp="C:\Temp\RipBot264temp" /GRANT:"%USER%",FULL
icacls "C:\Temp\RipBot264temp" /T /C /Q /Grant:R *%SID%:(OI)(CI)F
icacls "C:\Temp\RipBot264temp" /T /C /Q /inheritance:e

endlocal

pause

winner, winner, chicken dinner.. that's it, permissions correct now

D:\>if "Everyone" == "" (
echo No username found for S-1-1-0
exit /b 1
) else (echo Found username for S-1-1-0: Everyone )
Found username for S-1-1-0: Everyone

D:\>net share RipBot264temp /DELETE /Y
RipBot264temp was deleted successfully.


D:\>net share RipBot264temp="D:\Temp\RipBot264temp" /GRANT:"Everyone",FULL
RipBot264temp was shared successfully.


D:\>icacls "D:\Temp\RipBot264temp" /T /C /Q /Grant:R *S-1-1-0OI)(CI)F
Successfully processed 420 files; Failed processing 0 files

D:\>icacls "D:\Temp\RipBot264temp" /T /C /Q /inheritance:e
Successfully processed 420 files; Failed processing 0 files

[Atak_Snajpera]

Yeah. It also works on Windows 7 as well. I will update EncodingClient.exe this weekend with this new script...

Without DeepSeek AI I would have no idea how to get that EVERYONE string with powershell.

[rlev11]

Originally Posted by Atak_Snajpera

Yeah. It also works on Windows 7 as well. I will update EncodingClient.exe this weekend with this new script...

and you never know, Microsoft has a habit of re-checking depreciated stuff on occasion and removing it

[Atak_Snajpera]

do you still have WMIC.exe on updated PC?

[rlev11]

Originally Posted by Atak_Snajpera

do you still have WMIC.exe on updated PC?

checking, yes... know where you are going with this I think, I'll run the script on that one and make sure it doesn't go BOOM. give me a minute
Looks Good

D:\>set "SID=S-1-1-0"

D:\>set "USER="

D:\>for /F "delims=" %a in (' powershell -Command "$sid = New-Object System.Security.Principal.SecurityIdentifier('S-1-1-0'); try { $name = $sid.Translate([System.Security.Principal.NTAccount]).Value; Write-Output $name } catch { exit 1 }" ') do set "USER=%a"

D:\>set "USER=Everyone"

D:\>if "Everyone" == "" (
echo No username found for S-1-1-0
exit /b 1
) else (echo Found username for S-1-1-0: Everyone )
Found username for S-1-1-0: Everyone

D:\>net share RipBot264temp /DELETE /Y
RipBot264temp was deleted successfully.


D:\>net share RipBot264temp="D:\Temp\RipBot264temp" /GRANT:"Everyone",FULL
RipBot264temp was shared successfully.


D:\>icacls "D:\Temp\RipBot264temp" /T /C /Q /Grant:R *S-1-1-0OI)(CI)F
Successfully processed 1184 files; Failed processing 0 files

D:\>icacls "D:\Temp\RipBot264temp" /T /C /Q /inheritance:e
Successfully processed 1184 files; Failed processing 0 files

[Atak_Snajpera]

ok. So One problem solved. Time to bed now (it is after 02:00)...