Welcome to Doom9's Forum, THE in-place to be for everyone interested in DVD conversion.

Before you start posting please read the forum rules. By posting to this forum you agree to abide by the rules.

 

Go Back   Doom9's Forum > Capturing and Editing Video > Avisynth Usage

Reply
 
Thread Tools Search this Thread Display Modes
Old 5th September 2019, 17:23   #121  |  Link
Groucho2004
 
Join Date: Mar 2006
Location: Barcelona
Posts: 5,034
Quote:
Originally Posted by StainlessS View Post
Maybe ask G2K4 bout it, he's a nice fella and if you beg sufficiently well [bit of praise also works I hear], then maybe he do it. [EDIT: Refer to him as "My Leader", I believe he likes that]
Don't forget that I require a goat to be sacrificed before I start writing code.

@VoodooFX
I'll probably add that to the SysInfo() plugin.
__________________
Groucho's Avisynth Stuff
Groucho2004 is offline   Reply With Quote
Old 5th September 2019, 20:36   #122  |  Link
VoodooFX
Banana User
 
VoodooFX's Avatar
 
Join Date: Sep 2008
Posts: 985
I was thinking about some trick without external plugin.
I have seen on other forums newbies have problems with standalone MeGUI's avs+ not auto-loading ImageSeq.dll, error is not very clear what is wrong. I'll just catch that and assert with more clear msg then.
Requesting them to get more plugins not good idea.

Last edited by VoodooFX; 5th September 2019 at 20:43.
VoodooFX is offline   Reply With Quote
Old 5th September 2019, 22:06   #123  |  Link
Groucho2004
 
Join Date: Mar 2006
Location: Barcelona
Posts: 5,034
Quote:
Originally Posted by VoodooFX View Post
I was thinking about some trick without external plugin.
I have seen on other forums newbies have problems with standalone MeGUI's avs+ not auto-loading ImageSeq.dll, error is not very clear what is wrong. I'll just catch that and assert with more clear msg then.
Requesting them to get more plugins not good idea.
It's not possible as far as I know without some code that digs into the parent process and enumerates loaded modules.

As for megui's "portable" mode and plugins that were externalized in AVSPlus - I don't understand how this is even a problem, it seems ridiculous.
__________________
Groucho's Avisynth Stuff
Groucho2004 is offline   Reply With Quote
Old 7th October 2019, 04:39   #124  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
Quote:
Originally Posted by StainlessS View Post
you could try this

Code:
# SomeLogo.avs
# with Avisynth installed, play avs in most any player except VLC.                      # ie, get it working BEFORE try use in MeGUI
Colorbars(Pixel_Type="YV12").KillAudio                                                  # Testing subtstitute for your source video clip as YV12, ie delete line or comment out [insert '#' before line]
#AviSource("D:\Parade.avi").ConvertToYV12

I=ImageSource(".\Imagemagick-logo.png",END=0)                                           # Your Logo in current directory (or specify path)

#####  CONFIG #####
I_Width     = 128                                                                       # Your required width of Logo, multiple of 2
I_HEIGHT    = 96                                                                        # Your required Height of Logo, multiple of 2
LOGO_X      = -20                                                                       # Logo X position
LOGO_Y      = -20                                                                       # Logo Y position
RGT_REL     = True                                                                      # If True then LOGO_X adjusts right aligned, ie LOGO_X=0 is hard against Right hand side)
BOT_REL     = True                                                                      # If True then LOGO_Y adjusts Bottom aligned, ie LOGO_Y=0 is hard against bottom)
OPACITY     = 0.5                                                                       # 0.0 -> 1.0, 0.0=NO LOGO, 1=ALL LOGO
START_FRAME = 25
END_FRAME   = 100                                                                       # 0 = Do Till End of clip
### END CONFIG ###

Assert(I_WIDTH%2==0 &&I_HEIGHT%2==0,"SomeLogo: I_Width and I_Height have to be multiple of 2")
I=(I.Width!=I_WIDTH || I.Height != I_HEIGHT) ? I.Spline36Resize(I_WIDTH,I_HEIGHT) : I   # Resize to required
I=I.ConvertToYV12                                                                       # Same As Source clip
END_FRAME = (END_FRAME==0) ? Framecount-1 : END_FRAME
LOGO_X = (RGT_REL) ? (Width -I.Width  + LOGO_X) : LOGO_X
LOGO_Y = (BOT_REL) ? (Height-I.Height + LOGO_Y) : LOGO_Y
MASK=I.BlankClip(Color_YUV=$FF8080)                                                     # Solid White (just dummy for ApplyRange really)

(START_FRAME==0 && END_FRAME==FrameCount-1)
    \ ? Last.Overlay(I,x=LOGO_X,y=LOGO_Y,Opacity=OPACITY)
    \ : Last.ApplyRange(START_FRAME,END_FRAME,"Overlay",I,LOGO_X,LOGO_Y,MASK,OPACITY)

#return last.info                                                                        # Uncomment for TESTING

EDIT: Mod
Code:
# SomeLogo.avsi # Put in Avisynth Plugins AND MeGUI Plugins (NOTE, AVSI)
Function SomeLogo(clip c,clip Img,Int "I_Width",Int "I_Height",Int "Logo_X",Int "Logo_Y",Bool "Rgt_Rel",Bool "Bot_Rel",Float "Opacity",Int"Start_Frame",Int "End_Frame") {
    c                                                  # Last = c
    I_Width     = Default(I_Width, img.Width)          # Default original Image Width
    I_Height    = Default(I_Height,img.Height)         # Default original Image Height
    Logo_X      = Default(Logo_X,0)                    # Default 0
    Logo_Y      = Default(Logo_Y,0)                    # Default 0
    Rgt_Rel     = Default(Rgt_rel,False)               # Default False
    bot_Rel     = Default(bot_rel,False)               # Default False
    Opacity     = Default(Opacity,1.0)                 # Default 1.0, ALL image
    Start_Frame = Default(Start_Frame,0)               # Default frame 0
    End_Frame   = Default(End_Frame,0)                 # Default 0 = LAST FRAME
    Assert(I_WIDTH%2==0 &&I_HEIGHT%2==0,"SomeLogo: I_Width and I_Height have to be multiple of 2")
    Img=(Img.Width!=I_WIDTH || Img.Height != I_HEIGHT) ? Img.Spline36Resize(I_WIDTH,I_HEIGHT) : Img   # Resize to required
    Img=Img.ConvertToYV12                                                                             # Same As Source clip
    END_FRAME = (END_FRAME==0) ? Framecount-1 : END_FRAME
    LOGO_X = (RGT_REL) ? (Width -Img.Width  + LOGO_X) : LOGO_X
    LOGO_Y = (BOT_REL) ? (Height-Img.Height + LOGO_Y) : LOGO_Y
    MASK=Img.BlankClip(Color_YUV=$FF8080)                                                             # Solid White (just dummy for ApplyRange really)

    (START_FRAME==0 && END_FRAME==FrameCount-1)
        \ ? Last.Overlay(Img,x=LOGO_X,y=LOGO_Y,Opacity=OPACITY)
        \ : Last.ApplyRange(START_FRAME,END_FRAME,"Overlay",Img,LOGO_X,LOGO_Y,MASK,OPACITY)
    Return Last
}
# END SomeLogo.avsi    # For initial testing, can have above function in this test script, when move above to avsi in plugins, then remove above from this script.


# Your script calling the function in plugins [ someLogo.avsi : SomeLogo() ]
# with Avisynth installed, play avs in most any player except VLC.                      # ie, get it working BEFORE try use in MeGUI
Colorbars(Pixel_Type="YV12").KillAudio                                                  # Testing subtstitute for your source video clip as YV12, ie delete line or comment out [insert '#' before line]
#AviSource("D:\Parade.avi").ConvertToYV12

Img=ImageSource(".\Imagemagick-logo.png",END=0)                                         # Your Logo in current directory (or specify path)

#####  CONFIG #####
I_Width     = 128                                                                       # Your required width of Logo, multiple of 2
I_HEIGHT    = 96                                                                        # Your required Height of Logo, multiple of 2
LOGO_X      = -20                                                                       # Logo X position
LOGO_Y      = -20                                                                       # Logo Y position
RGT_REL     = True                                                                      # If True then LOGO_X adjusts right aligned, ie LOGO_X=0 is hard against Right hand side)
BOT_REL     = True                                                                      # If True then LOGO_Y adjusts Bottom aligned, ie LOGO_Y=0 is hard against bottom)
OPACITY     = 0.5                                                                       # 0.0 -> 1.0, 0.0=NO LOGO, 1=ALL LOGO
START_FRAME = 25
END_FRAME   = 100                                                                       # 0 = Do Till End of clip
### END CONFIG ###

SomeLogo(Img,I_Width=I_WIDTH,I_Height=I_HEIGHT,Logo_X=LOGO_X,Logo_Y=LOGO_Y,Rgt_Rel=RGT_REL,Bot_Rel=BOT_REL,Opacity=OPACITY,Start_Frame=START_FRAME,End_Frame=END_FRAME)
#SomeLogo(Img,128,96,Opacity=0.5,Start_Frame=25,End_Frame=100)                          # Logo_X, Logo_Y,Rgt_Rel, Bot_rel, ALL DEFAULT ::: ALL CONFIG part can be missed out
#SomeLogo(Img,128,96,-20,-20,true,true,0.5,0,100)                                       # ALL CONFIG part can be missed out

#return last.info                                                                       # Uncomment for TESTING
EDIT: So with SomeLogo.avsi in plugins, can use just like so:-
Code:
Colorbars(Pixel_Type="YV12").KillAudio                                                  # Testing subtstitute for your source video clip as YV12, ie delete line or comment out [insert '#' before line]
Img=ImageSource(".\Imagemagick-logo.png",END=0)                                         # Your Logo in current directory (or specify path)
SomeLogo(Img,128,96,-20,-20,true,true,0.5,0,100)                                        # ALL CONFIG part can be missed out
#SomeLogo(Img,I_Width=128,I_Height=96,Logo_X=-20,Logo_Y=-20,Rgt_Rel=True,Bot_Rel=True,Opacity=0.5,Start_Frame=0,End_Frame=100) #  ALL CONFIG part can be missed out
Thanks a Lot and sorry for not replied
imsrk48 is offline   Reply With Quote
Old 15th October 2019, 23:32   #125  |  Link
eobard
Registered User
 
Join Date: Oct 2019
Posts: 8
Is there a mirror of avisynth.nl? The site is down
eobard is offline   Reply With Quote
Old 16th October 2019, 02:50   #126  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 10,980
Its up now.
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???
StainlessS is offline   Reply With Quote
Old 21st November 2019, 10:46   #127  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
i want to learn avisynth where i can start?
imsrk48 is offline   Reply With Quote
Old 21st November 2019, 10:58   #128  |  Link
l00t
Where's my loot?
 
Join Date: May 2019
Posts: 63
Quote:
Originally Posted by imsrk48 View Post
i want to learn avisynth where i can start?
http://avisynth.nl/index.php/Main_Page

-> New to AviSynth - Start here
l00t is offline   Reply With Quote
Old 21st November 2019, 11:32   #129  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
Quote:
Originally Posted by l00t View Post
http://avisynth.nl/index.php/Main_Page



-> New to AviSynth - Start here
Thanks a Lot
imsrk48 is offline   Reply With Quote
Old 24th December 2019, 14:06   #130  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
i would like to ask can avisynth increase video quality or 240p video to 720p with some scripts?

https://tune.pk/video/7484297/hatim-episode-1
imsrk48 is offline   Reply With Quote
Old 24th December 2019, 17:16   #131  |  Link
FranceBB
Broadcast Encoder
 
FranceBB's Avatar
 
Join Date: Nov 2013
Location: Royal Borough of Kensington & Chelsea, UK
Posts: 2,883
Quote:
Originally Posted by imsrk48 View Post
i would like to ask can avisynth increase video quality or 240p video to 720p with some scripts?

https://tune.pk/video/7484297/hatim-episode-1
Upscaling won't increase video quality as you can't create pixels out of nowhere.
Anyway, there are good upscaling kernels that can upscale a source quite nicely like Spline64 which you can use together with NNEDI.
Please note that - as I said - although you are gonna have more pixels, you won't have more definition as those new pixels are just gonna be "fake". Some argue that upscaling doesn't bring any benefit at all and it's just a waste of space, but on the other hand some other people argue that sometimes it's worth upscaling as it's better to do it with Avisynth than to let the TV or the player do it with something crappy like a FastBilinear. As to your source, it seems to be starved which basically means that whoever encoded it did it at a very low bitrate thus removing important details.
With a source like this, upscaling is the LAST thing I would do.
If you really wanna re-encode it, just do deblocking with Deblock_QED() or the built-in deblocker of x264/x265 if you're planning to re-encode it in H.264/H.265 and a bit of denoise with dfttest(). It will look flat, but at least you won't have macroblocks and ringing everywhere.



By the way...

You linked a streaming website that I don't know, but I highly doubt that it's legal, so if it isn't, moderators will remove your link and you won't receive any further help as piracy is forbidden!

I just did a google search of the series and the first thing I found is a website with the DVDs of the series you linked. I strongly suggest you to get the official DVDs which are gonna be a relatively high bitrate MPEG-2 encodes at 720x480i which are far better than the crappy starved 240p source you linked.

Last edited by FranceBB; 24th December 2019 at 17:19.
FranceBB is offline   Reply With Quote
Old 24th December 2019, 18:07   #132  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 10,980
+1 for what FranceBB said, tis truly garbage.
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???
StainlessS is offline   Reply With Quote
Old 24th December 2019, 19:06   #133  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
Quote:
Originally Posted by FranceBB View Post
Upscaling won't increase video quality as you can't create pixels out of nowhere.
Anyway, there are good upscaling kernels that can upscale a source quite nicely like Spline64 which you can use together with NNEDI.
Please note that - as I said - although you are gonna have more pixels, you won't have more definition as those new pixels are just gonna be "fake". Some argue that upscaling doesn't bring any benefit at all and it's just a waste of space, but on the other hand some other people argue that sometimes it's worth upscaling as it's better to do it with Avisynth than to let the TV or the player do it with something crappy like a FastBilinear. As to your source, it seems to be starved which basically means that whoever encoded it did it at a very low bitrate thus removing important details.
With a source like this, upscaling is the LAST thing I would do.
If you really wanna re-encode it, just do deblocking with Deblock_QED() or the built-in deblocker of x264/x265 if you're planning to re-encode it in H.264/H.265 and a bit of denoise with dfttest(). It will look flat, but at least you won't have macroblocks and ringing everywhere.



By the way...

You linked a streaming website that I don't know, but I highly doubt that it's legal, so if it isn't, moderators will remove your link and you won't receive any further help as piracy is forbidden!

I just did a google search of the series and the first thing I found is a website with the DVDs of the series you linked. I strongly suggest you to get the official DVDs which are gonna be a relatively high bitrate MPEG-2 encodes at 720x480i which are far better than the crappy starved 240p source you linked.
my question according to super resolution plug-in and this is a tv show there's official DVDs not available anywhere. that's why I'm asking btw I'm sorry for using increase quality basically I'm try to asking "how upscale pixels" that you answered

Last edited by imsrk48; 24th December 2019 at 19:11.
imsrk48 is offline   Reply With Quote
Old 24th December 2019, 20:36   #134  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 10,980
On Amazon, Currently Unavailable:- https://www.amazon.in/Hatim-Star-Plu.../dp/B07RNCKZP5

Quote:
Bad quality,plz fix it...
Quote:
I was searching for it for last 5-6 years,but i didn't find any CD or DVD of it.
And at last i got it from amazon.
I was searching for it for better video quality like HD 720p but there is only in 244p which i already have in 360p.
Plz bring it in high resolution, then i will again buy it
Plz plz plz plz plz plz bring it in HD.
THANKS
Quote:
Price is high
Here on SnapDeal (seems available, Rs 5000 rupees):- https://www.snapdeal.com/product/the...d/627087430366
Given prev quotes, might also be rubbish.

Google Search "Hatim DVD"
https://www.google.com/search?ei=QmY...4dUDCAo&uact=5

Good Luck.

EDIT: @ 1 Rupee = £0.011, I make it about £55.00 on Snapdeal, for a garbage DVD [assuming previous quotes also apply to SnapDeal DVD].
Suggest dont waste your money.
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???

Last edited by StainlessS; 25th December 2019 at 16:42.
StainlessS is offline   Reply With Quote
Old 25th December 2019, 16:51   #135  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
Quote:
Originally Posted by StainlessS View Post
On Amazon, Currently Unavailable:- https://www.amazon.in/Hatim-Star-Plu.../dp/B07RNCKZP5







Here on SnapDeal (seems available, Rs 5000 rupees):- https://www.snapdeal.com/product/the...d/627087430366
Given prev quotes, might also be rubbish.

Google Search "Hatim DVD"
https://www.google.com/search?ei=QmY...4dUDCAo&uact=5

Good Luck.

EDIT: @ 1 Rupee = £0.011, I make it about £55.00 on Snapdeal, for a garbage DVD [assuming previous quotes also apply to SnapDeal DVD].
Suggest dont waste your money.
imsrk48 is offline   Reply With Quote
Old 26th December 2019, 02:57   #136  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 10,980
Imsrk48,

Below is auto generated from a much bigger script.
Source has a weird ripple effect, I think may have been in XVID/DIVX at some point.
Also sections have duplicates where seems to be about 2/3 framerate of the source 24FPS, this messes with motion compensation stuff.
Could stand getting rid of the logos at bottom [see InPaintDelogo thread].
About as much time as I would be prepared to spend on it [although many have spent a long time trying to repair worse clips]

Code:
V=LSmashVideoSource(".\Hatim Episode 1 - Tunepk.mp4")                   # LSmash Plugin
A=LSmashAudioSource(".\Hatim Episode 1 - Tunepk.mp4")
AudioDub(V,A)
ORG=Last

# Below auto generated from Manual settings
Deblock(28)                                                             # Plugin (might want to adjust this value)

Cropped=Crop(0,0,0,0,align=true)

# AutoLevels from my MediaFire account, v0.12Beta3_20190711
Cropped.AutoLevels(
  \ FilterRadius=12,
  \ gamma=UnDefined,
  \ AutoGamma=False,
  \ midpoint=0.500000,
  \ input_low=UnDefined,
  \ input_high=UnDefined,
  \ ignore_low=0.001953,
  \ ignore_high=0.001953,
  \ border_l=0,
  \ border_r=0,
  \ border_t=0,
  \ border_b=0,
  \ Debug=False,
  \ sc2Th=8,
  \ sc2Perc=33.333332,
  \ gammax=1.500000,
  \ gammin=0.666667,
  \ MinRng=100)

McDegrainSharp(frames=2,csharp=0.333000,Precise=False)                   # http://forum.doom9.org/showthread.php?p=1737045#post1737045 [Might want to adjust frames (1->3)]
nnedi3_rpow2(rfactor=4,cshift="Spline36Resize",fwidth=960,fheight=720)   # Plugin   (960x720=4:3)

Limiter(16,235,16,240)

AudioDub(Last,MergeChannels(GetChannel(1),GetChannel(1)))                # Make 2 channel
ResampleAudio(44100)                                                     # from 22.50 KHz

MeGUI_DarX=4 MeGUI_DarY=3                                                # Auto set Megui DAR : SnapDeal says DAR is 16:10, looks more like 4:3 to me.

Trim(0,0)                                                                # chop/pad audio to match video length
Return Last
Return StackHorizontal(ORG.Spline36Resize(960,720),Last)                 # Original on left, Doctored on right. # COMMENT OUT Above Return Last
Again, Good Luck.

EDITED as per later post.
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???

Last edited by StainlessS; 26th December 2019 at 04:23.
StainlessS is offline   Reply With Quote
Old 26th December 2019, 04:03   #137  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
Quote:
Originally Posted by StainlessS View Post
Imsrk48,

Below is auto generated from a much bigger script.
Source has a weird ripple effect, I think may have been in XVID/DIVX at some point.
Also sections have duplicates where seems to be about 2/3 framerate of the source 24FPS, this messes with motion compensation stuff.
Could stand getting rid of the logos at bottom [see InPaintDelogo thread].
About as much time as I would be prepared to spend on it [although many have spent a long time trying to repair worse clips]

Code:
V=LSmashVideoSource(".\Hatim Episode 1 - Tunepk.mp4")                   # LSmash Plugin
A=LSmashAudioSource(".\Hatim Episode 1 - Tunepk.mp4")
AudioDub(V,A)


# Below auto generated from Manual settings
Deblock(28)                                                             # Plugin (might want to adjust this value)

Cropped=Crop(0,0,0,0,align=true)

# AutoLevels from my MediaFire account, v0.12Beta3_20190711
Cropped.AutoLevels(
  \ FilterRadius=12,
  \ gamma=UnDefined,
  \ AutoGamma=False,
  \ midpoint=0.500000,
  \ input_low=UnDefined,
  \ input_high=UnDefined,
  \ ignore_low=0.001953,
  \ ignore_high=0.001953,
  \ border_l=0,
  \ border_r=0,
  \ border_t=0,
  \ border_b=0,
  \ Debug=False,
  \ sc2Th=8,
  \ sc2Perc=33.333332,
  \ gammax=1.500000,
  \ gammin=0.666667,
  \ MinRng=100)

McDegrainSharp(frames=2,csharp=0.333000,Precise=False)                   # http://forum.doom9.org/showthread.php?p=1737045#post1737045 [Might want to adjust frames (1->3)]
nnedi3_rpow2(rfactor=4,cshift="Spline36Resize",fwidth=960,fheight=720)   # Plugin   (960x720=4:3)

Limiter(16,235,16,240)

AudioDub(Last,MergeChannels(GetChannel(1),GetChannel(1)))                # Make 2 channel
ResampleAudio(44100)                                                     # from 22.50 KHz

MeGUI_DarX=4 MeGUI_DarY=3                                                # Auto set Megui DAR : SnapDeal says DAR is 16:10, looks more like 4:3 to me.

Trim(0,0)                                                                # chop/pad audio to match video length
Return Last
Again, Good Luck.
Thanks a lot sir for your huge kind and hard work
imsrk48 is offline   Reply With Quote
Old 26th December 2019, 04:14   #138  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 10,980
imsrk48,

There is not a huge difference, but there is some.
Can compare with simple Spline36Resize using below.

After AudioDub line add
Code:
ORG=Last
Replace Return last line with
Code:
Return StackHorizontal(ORG.Spline36Resize(960,720),Last)                 # Original on left, Doctored on right.
View in VirtualDub2
[EDIT: See my prev post, marked in Blue]
Could use above to adjust eg Deblock() arg whilst seeing before and after frames.

MysteryX did some supposed SuperRez thing [EDIT: in devs forum] , dont know if would produce any great improvement [never used it].

EDIT:
Also, in future, might be better to start your own thread [its quite easy], this thread is really about eg changes in avisynth itself [or questions about avisynth], rather than processing video.
People may be more reluctant to answer video processing questions when posted in the wrong thread.

EDIT: You might want to try with deblock() lowered or completely removed, see what it looks like (DeBlock can fix some types of blocking, but can also cause damage, its a balancing act).
Also, it may be that some of the blocking is from before 1 or more resizes to the source, if so then using deblock cannot help for that blocking, its burned in.
The Baby Face, near beginning does benefit from deblock , maybe use those frames to get best setting, try not to go too high, I think max is about 30 or 32.

csharp adjusts sharpness in McDegrainSharp [McDegrainSharp(frames=2,csharp=0.333000,Precise=False)], default is 0.6 but I tend to
use 0.3 or thereabouts for MY default, suggest dont go above 0.6.

EDIT: Another version to try. Switched on NonLinUSM in script generator, & slight mods to script generator defaults.
Code:
V=LSmashVideoSource(".\Hatim Episode 1 - Tunepk.mp4")                   # LSmash Plugin
A=LSmashAudioSource(".\Hatim Episode 1 - Tunepk.mp4")
AudioDub(V,A)
ORG=Last

# Below auto generated from Manual/Auto_detected, settings

Deblock(20)                                                        # Reduced from 24

Cropped=Crop(0,0,0,0,align=true) # QueryBorderCropped And/Or Remove Padding for prev DeBlock filter
Cropped.AutoLevels(
  \ FilterRadius=12,
  \ gamma=UnDefined,
  \ AutoGamma=False,
  \ midpoint=0.500000,
  \ input_low=UnDefined,
  \ input_high=UnDefined,
  \ ignore_low=0.001000,
  \ ignore_high=0.001000,
  \ border_l=0,
  \ border_r=0,
  \ border_t=0,
  \ border_b=0,
  \ Debug=False,
  \ sc2Th=8,
  \ sc2Perc=33.333332,
  \ gammax=1.100000,
  \ gammin=0.909091,
  \ MinRng=100)

McDegrainSharp(2,csharp=0.300000,Precise=False)  # Pre-Upsize # have reduced (a little) to 0.3, sharpness csharp, 0.0 -> 0.6

nnedi3_rpow2(rfactor=4,cshift="Spline36Resize",fwidth=960,fheight=720)       # Upsize

NonlinUSM(z=3,  pow=1.100000, str=0.250000, rad=9)                           # ADDED: Search NonlinUSM script : Can Mod local contrast, suggest str 0.2 - 0.33

Limiter(16,235,16,240)   # Limit to TV_Levels range

AudioDub(Last,MergeChannels(GetChannel(1),GetChannel(1)))  # Matching to required output, 2 audio channels
ResampleAudio(44100) # Match to required Audio SampleRate

MeGUI_DarX=4 MeGUI_DarY=3

Trim(0,0) # chop/pad audio to match video length
#Return Last # End of Generated Script
Return StackHorizontal(ORG.Spline36Resize(960,720),Last)
NonlinUSM is a sort of local contrast, pixel luma contrast adjusted with respect to pixels near to it, will look somewhat like sharpening and probably be
most evident in eg hair. If I use it, I usually use 0.25 or 0.33. Can just comment out that line if you dont like it.

EDIT: From the clip, seems to be a Hindi, "Lord Of The Rings" clone.
EDIT: Added some comments in script generator, marked above in RED
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???

Last edited by StainlessS; 27th December 2019 at 00:37.
StainlessS is offline   Reply With Quote
Old 27th December 2019, 05:33   #139  |  Link
imsrk48
Registered User
 
imsrk48's Avatar
 
Join Date: Nov 2017
Posts: 154
Okay Sir,

Please someone suggest me all Softwares that working with Avisynth.

I'm trying to learn Avisynth.
imsrk48 is offline   Reply With Quote
Old 27th December 2019, 06:15   #140  |  Link
StainlessS
HeartlessS Usurer
 
StainlessS's Avatar
 
Join Date: Dec 2009
Location: Over the rainbow
Posts: 10,980
See Wiki [see everything on wiki homepage] :- http://avisynth.nl/index.php/Main_Page

Internal filters:- http://avisynth.nl/index.php/Internal_filters
External Filters:- http://avisynth.nl/index.php/External_filters
__________________
I sometimes post sober.
StainlessS@MediaFire ::: AND/OR ::: StainlessS@SendSpace

"Some infinities are bigger than other infinities", but how many of them are infinitely bigger ???
StainlessS is offline   Reply With Quote
Reply

Tags
avisynth, faq

Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump


All times are GMT +1. The time now is 03:13.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2024, vBulletin Solutions Inc.